**Supplement: Bayesian mixture model details**

We used a Bayesian mixture model to describe the lengths of the observed juvenile O. Mykiss. Fish were assumed to be age, 0, 1 or 2, with between year and tributary differences in length at age relationships. We fit the model using the JAGS Bayesian statistical software (Plummer 2003) with the R language (R core team 2020) as an interface. We checked for model convergence by visually inspecting the trace plots for important parameters and Rhat values (Gelman and Rubin 1992).

JAGS code:

model{

for(i in 1:fish){

L[i] ~ dnorm(mu[i],tau[i])

mu[i] <- muAge[age[i]]\*exp(yearMu[year[i]] + tributaryMu[tributary[i]]) + a\*jDate[i]

tau[i] <- pow(sd[i],-2)

sd[i] <- sdAge[age[i]]

age[i] ~ dcat(pp[])

}

pp ~ ddirch(alpha[])

# priors on mean and sd of lengths by age

muAge[1] ~ dnorm(muAgeMu[1], 0.001)

sdAge[1] ~ dnorm(sdAgeMu[1], 0.001)

for(m in 2:3){

muAge[m] <- muAge[m-1] + dd[m-1]

dd[m-1] ~ dnorm(muAgeMu[m]-muAgeMu[m-1], 0.01)T(0,)

sdAge[m] ~ dnorm(sdAgeMu[m], 0.001)

}

# vague prior for effect of date (linear growth)

a ~ dunif(0.20,0.80)

# random effect for years

for(j in 1:years){

yearMu[j] ~ dnorm(0,tauSE)

}

tauSE <- pow(sdSE,-2)

sdSE ~ dunif(0,100)

# fixed effect for tributaries (sum to zero constraint)

tributaryMu[1] <- -sum(tributaryMu[2:tributaries])

for(k in 2:tributaries){

tributaryMu[k] ~ dnorm(0,0.001)

}

}

Constants (prior parameters)

muAgeMu = (20,100,175); sdAgeMu = (10,15,25); alpha = (1,1,1)